• 응용 프로그램을 생성하고 열거하는 방법
• 응용 프로그램 풀을 생성하고, 구성하고, 삭제하는 방법
• 응용 프로그램 풀을 시작하고, 중지하고, 재생하는 방법
• 응용 프로그램 풀의 상태를 조회하는 방법
• 서버상에 존재하는 모든 응용 프로그램 풀의 목록을 얻는 방법

• IIS 설치 및 스크립팅 활성화 *
  • 만약, 윈도우 비스타를 사용중이라면, 제어판에서 "프로그램 및 기능" 을 열고, "Windows 기능 사용/사용 안 함" 을 실행합니다. 그리고, "웹 관리 도구" 하위의 "IIS 관리 스크립트 및 도구" 항목을 선택하여 스크립팅을 활성화시킵니다.
  • 만약, 롱혼 서버를 사용중이라면, 서버 관리자를 실행합니다. 그리고, Add Roles Wizard 를 사용하여 IIS 웹 서버를 설치합니다. 설치 과정 중, Select Role Services 페이지에서 Management Tools 하위의 "IIS Management Scripts and Tools" 항목을 선택합니다.
• 관리자 권한으로 명령 프롬프트를 실행합니다. 일단 명령 프롬프트가 관리자 권한으로 실행되면, 이 명령 프롬프트에서 실행되는 모든 응용 프로그램들이 관리자 권한으로 실행됩니다. 또한, 스크립트 파일을 .VBS 확장자를 가진 텍스트 파일 형식으로 저장하십시오. 이와 같은 스크립트 파일들은 명령 프롬프트상에서 "cscript.exe <scriptname>.vbs" 형식의 명령을 입력하여 실행할 수 있습니다.
• 본문의 내용을 시작하기 전에, 먼저 System32\inetsrv\config\applicationhost.config 파일의 백업본을 만들어 두십시오. 이 백업본 파일을 다시 덮어 쓰는 것만으로도 IIS 를 기존 상태로 복구할 수 있습니다. **

Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")



' 새로운 응용 프로그램을 위한 Path 인자, SiteName 인자, PhysicalPath 인자를 정의합니다.

strApplicationPath = "/NewApp"

strSiteName = "Default Web Site"

strPhysicalPath = "D:\inetpub\NewApp"



' 새로운 응용 프로그램을 생성합니다.

oWebAdmin.Get("Application").Create strApplicationPath, strSiteName, strPhysicalPath

' WMI WebAdministration 네임스페이스에 연결합니다.

Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")



' InstancesOf 메서드를 사용하여 응용 프로그램 목록을 조회합니다.

Set oApps = oWebAdmin.InstancesOf("Application")



' 응용 프로그램에 대한 반복처리를 수행합니다.

For Each oApp In oApps

    WScript.Echo "  Web site/Application: " & oApp.SiteName & oApp.Path

    WScript.Echo "      Application Pool: " & oApp.ApplicationPool

    WScript.Echo "   Enabled protocol(s): " & oApp.EnabledProtocols

    WScript.Echo

Next

*	비스타 SP 1 RTM 상에서 직접 테스트를 해보니 다음과 같은 오류가 발생하였다. 그리고, 2008 RC1 상에서 테스트를 해보니 이번에는 다음과 같은 오류가 발생하였다.

Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")

oWebAdmin.Get("ApplicationPool").Create("NewAppPool")

Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")



strNewAppPoolName = InputBox("Enter the name for the new application pool.")



If strNewAppPoolName <> "" Then

    oWebAdmin.Get("ApplicationPool").Create(strNewAppPoolName)

End If

Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")



' MyApp 응용 프로그램을 얻습니다.

Set oApp = oWebAdmin.Get("Application.SiteName='Default Web Site',Path='/MyApp'")

WScript.Echo "Application Web site and Path: '" & oApp.SiteName & oApp.Path & "'"

WScript.Echo "Old application pool: " & oApp.ApplicationPool

WScript.Echo



' 새로운 응용 프로그램 풀의 이름을 지정합니다.

oApp.ApplicationPool = "NewAppPool"



' 변경 사항을 저장합니다.

oApp.Put_



' 새로운 응용 프로그램 풀의 이름을 출력합니다.

WScript.Echo

WScript.Echo "New application pool: " & oApp.ApplicationPool

Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")



Set oAppPools = oWebAdmin.InstancesOf("ApplicationPool")

For Each oAppPool In oAppPools

    If oAppPool.Name = "UnwantedAppPool" Then

        oAppPool.Delete_

        Exit For

   End If

Next

Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")



' 기본 웹 사이트를 얻습니다.

Set oSite = oWebAdmin.Get("Site.Name='Default Web Site'")



' 기본 응용 프로그램 풀 이름을 지정합니다.

oSite.ApplicationDefaults.ApplicationPool = "NewAppPool"



' 변경 사항을 저장합니다.

oSite.Put_

*	본문에서 제시하는 스크립트와 같이 특별히 파이프라인 모드를 지정하지 않고 응용 프로그램 풀을 생성하면 다음과 같이 파이프라인 모드가 통합 모드로 생성된다.
**	이 스크립트를 테스트 할 때, 테스트에 사용되는 응용 프로그램의 이름에 주의하기 바란다. 즉 본문의 모든 다른 스크립트 샘플 코드는 "/NewApp" 라는 이름의 응용 프로그램을 대상으로 작업을 수행하지만, 이 스크립트 샘플 코드에서만은 "/MyApp" 라는 이름의 응용 프로그램을 대상으로 작업을 수행한다. 따라서, 코드를 그대로 복사하여 실행하면 전혀 예상하지 못했던 오류를 만나게 될 것이다.

' WMI WebAdministration 네임스페이스에 연결합니다.

Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")



' 응용 프로그램 풀을 지정합니다.

Set oAppPool = oWebAdmin.Get("ApplicationPool.Name='DefaultAppPool'")



' 응용 프로그램 풀을 시작합니다.

oAppPool.Start

' WMI WebAdministration 네임스페이스에 연결합니다.

Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")



' 응용 프로그램 풀을 지정합니다.

Set oAppPool = oWebAdmin.Get("ApplicationPool.Name='DefaultAppPool'")



' 응용 프로그램 풀을 중지합니다.

oAppPool.Stop

' WMI WebAdministration 네임스페이스에 연결합니다.

Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")



' 응용 프로그램 풀을 지정합니다.

Set oAppPool = oWebAdmin.Get("ApplicationPool.Name='DefaultAppPool'")



' 응용 프로그램 풀을 재생합니다.

oAppPool.Recycle

Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")

Set oAppPool = oWebAdmin.Get("ApplicationPool.Name='DefaultAppPool'")



' 응용 프로그램 풀의 이름과 상태를 얻습니다.

WScript.Echo oAppPool.Name & " is " & GetStateDescription(oAppPool.GetState) & "."



' 리턴값을 텍스트로 변환해주는 함수.

Function GetStateDescription(StateCode)

    Select Case StateCode

        Case 0

            GetStateDescription = "Starting"

        Case 1

            GetStateDescription = "Started"

        Case 2

            GetStateDescription = "Stopping"

        Case 3

            GetStateDescription = "Stopped"

        Case 4

            GetStateDescription = "Unknown"

        Case Else

            GetStateDescription = "Undefined value."

    End Select

End Function

Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")

Set oAppPools = oWebAdmin.InstancesOf("ApplicationPool")



For Each oAppPool In oAppPools



    WScript.Echo "Application pool name: " & oAppPool.Name



    If oAppPool.ManagedPipelineMode = 0 Then

        sAppPoolMode = "Integrated"

    ElseIf oAppPool.ManagedPipelineMode = 1 Then

        sAppPoolMode = "ISAPI"

    End if



    WScript.Echo "Application pool mode: " & sAppPoolMode

    WScript.Echo 



Next

Application pool name: DefaultAppPool

Application pool mode: Integrated



Application pool name: Classic .NET AppPool

Application pool mode: ISAPI

• 응용 프로그램을 생성하고 열거하는 방법
• 응용 프로그램 풀을 생성하고, 구성하고, 삭제하는 방법
• 응용 프로그램 풀을 시작하고, 중지하고, 재생하는 방법
• 응용 프로그램 풀의 상태를 조회하는 방법
• 서버상에 존재하는 모든 응용 프로그램 풀의 목록을 얻는 방법

宋