login register Sysop! about ME  

2007년 11월 22일 11시 10분 00초,     조회수 : 591
  제목 : Re : 쇼핑몰에서 오늘본상품 구현 질문입니다.
SEQ : 144037 글쓴이 : jimmy

작성 포맷 : TEXT 모드, 자동 줄바꿈 사용

쿠키, 세션등도 배열을 지원합니다.
오늘본 상품구현에도 배열을 이용하면 좀더 쉽겠지요.
아래는 현재 사용되고 있는 소스이니 참고하세요.

------------------------------------------------------------------------------------------------

   '오늘본상품 저장

   ToDayGoodsSet SG_CODE, SG_IMG '함수호출 상품코드, 상품이미지

   Sub ToDayGoodsSet(SG_CODE,SG_IMG)
      C_Goods = Request.Cookies("TodayGcode")
      C_Count = Request.Cookies("TodayGcode").count
      If C_Goods = "" OR C_Count = "" Then C_Count = 0
      If C_Count > 19 Then C_Count = 19 '20개까지 저장을 의미
      
      If InStr(C_Goods, "=" & SG_CODE) = 0 Then '저장된게 없으면 기존것은 배열에서 1씩 뒤로저장
         For c_cnt = C_Count To 1 Step -1
            Response.Cookies("TodayGcode")("G" & c_cnt + 1) = Request.Cookies("TodayGcode")("G" & c_cnt)
            Response.Cookies("TodayImg")("G" & c_cnt + 1) = Request.Cookies("TodayImg")("G" & c_cnt)
         Next
      
         '첫번째 배열에 신규상품 저장
         Response.Cookies("TodayGcode")("G1") = SG_CODE
         Response.Cookies("TodayImg")("G1") = SG_IMG
      End If

      '쿠기 expires(만기)일 및 사용허용 도메인설정 만기일설정은 1일로 함
      NewDate = DateAdd("d", 1, Now())
      Response.Cookies("TodayGcode").expires = NewDate
      Response.Cookies("TodayGcode").path = "/"
      Response.Cookies("TodayGcode").Domain = Request.ServerVariables("SERVER_NAME")
      Response.Cookies("TodayImg").expires = NewDate
      Response.Cookies("TodayImg").path = "/"
      Response.Cookies("TodayImg").Domain = Request.ServerVariables("SERVER_NAME")
   End Sub

------------------------------------------------------------------------------------------------

   '오늘본상품보기

   T_Goods = Request.Cookies("TodayGcode")
   T_Count = Request.Cookies("TodayGcode").count
   If T_Goods = "" OR T_Count = "" Then T_Count = 0
   If T_Count > 20 Then T_Count = 20

   For g_cnt = 1 To T_Count
      TodayGcode = Request.Cookies("TodayGcode")("G" & g_cnt)
      TodayImg = Request.Cookies("TodayImg")("G" & g_cnt)
      
      response.write TodayGcode & "<br>"
   Next

------------------------------------------------------------------------------------------------

   G & 번호로 쓰는 이유는 번호만으로 쿠키를 만들면 제대로 동작하지 않습니다.
   즉 문자열은 되나 숫자는 안된다는 말이지요.

   If InStr(C_Goods, "=" & SG_CODE) = 0 Then 
   이부분이 기존 쿠키에 들어있느냐를 비교하여 주는 부분입니다. InStr이 문자열 비교입니다.
   1차원 배열인 Request.Cookies("TodayGcode")에 저장되는 값이
   G1=코드,G2=코드,..... 아미도 이렇게 저장이 되어 있을것입니다. 문자열 비교하면 쉽게 해결된답니다.

   상품보기는 위와같이 디자인에 맞게 뿌려주시면되겠지요.
   쇼핑몰에서는 20개정도 저장하고 위아래로 이동버튼을 만들어 5개정도 볼수 있도록 하는데
   javascript를 잘 활용하면 될것입니다. 안되면 다른 사이트 javascript를 참고해보시고여~



   웹짱닷넷 사이트를 운영하고 있는데 한번 들려보세요.
   ASP 새로운 프로그램의 세계를 만나게 되실지도~

   http://www.webjjang.net

  ksyu21
  2007-11-23(01:15)
정말 정말 너무 너무 감사해요. 덕분에 쉽게 해결이 되었어요..^^


제목 작성자 날짜 조회
쇼핑몰에서 오늘본상품 구현 질문입니다. (1) ksyu21 2007-11-22 481
Re : 쇼핑몰에서 오늘본상품 구현 질문입니다. (1) jimmy 2007-11-22 591

 
 
.NET과 Java 동영상 기반의 교육사이트

로딩 중입니다...

서버 프레임워크 지원 : NeoDEEX
based on ASP.NET 3.5
Creative Commons License
{5}
{2} 읽음   :{3} ({4})