Taeyo's ASP.NET

lecture Home > ASP Tips > Danny's 일정 관리 시스템 만들기

Danny's 일정 관리 시스템 만들기

강좌 최초 작성일 : 2004년 06월 20일
강좌 최종 수정일 : 2004년 06월 23일

강좌 읽음 수 : 회

작성자 : Danny(전 성대)
편집자 : Taeyo(김 태영)

강좌 제목 : 일정 관리 시스템 만들기(2)

강좌 전 태오의 잡담>

상당히 업데이트가 빠른 대니님의 강좌입니다. 매우 열심이신걸요~~ ^^
Passion을 가진 모든 분들은 다 멋져 보입니당. 핫핫핫..
또한, 그것이 바로 제가 멋진 이유 아니겠습니까??? @_@;;;;

강좌 시작 >

안녕하세요. 대니입니다.

대니의 일정관리는 디자인이라고는 찾아볼수가 없음을 미리 알려드립니다.^^; (디자인 잘되어있으면 수정하기 힘드시잖아요 ㅡ,.ㅡ)

이제 본격적으로 달력을 만들어 봐야 하겠는데요...달력은 너무 길기때문에 #2회로 나누어 설명드리고자 합니다. 일정관리에서 제일 중요하면서도 머리털 많이 빠지는곳이 바로 달력입니다.(장담할순 없지만..경험상..) 1일 부터 가끔은 31일까지 나오기도하고, 음력으로는 4년마다 한번씩 윤달이 들기도 하며, 어떤 해에는 2월달의 일수가 바뀌기도 합니다.

또 정기적인 기념일이 있을때는 설이나 추석처럼 음력기념일이 있는가 하면, 성탄절이나 광복절처럼 양력기념일이 있기도 합니다. 뭐~ 특이사항으로는 성년의 날은 5월 3째주 월요일이 기념일이기도 합니다.(실제 이런 내용들을 알지 못하고 코드를 보실경우엔 전혀 이해하실수 없을지도 모르기 때문에 대략적으로 설명드립니다.)

뭐 이해할 수 없으시다면 그냥 지금까지.. 강좌보시는 분들은 정말 땡잡으셨다는 대니의 글이라고 해석해 주시면 되겠구요(날아드는 돌맹이들--;) 본론으로 들어가서 이런 개념들은 모두 달력을 보고 이해하시기 바라며 대니가 모두 설명드릴수 없다는점 잘 아시리라 믿습니다. 믿구요.(설명드리자면 페이지가 많아져서 태오아저씨에게 경고먹을지도...^^; [이에 대한 태오의 추가멘트] 강좌는 얼마든지 길어도 좋아요~ 책처럼 페이지가 많아진다구 가격이 올라가는게 아니니깐~) 대니의 잡스러운 코드를 이해해 주시라는 양해의 말씀을 드리고자 합니다.

그럼 본론으로 들어가서(대체 몇번이나 본론을 들어가는거야..히죽^-^), 기본적으로 달력을 만들때 가지고 다녀야하는 값들과 양력을 위주로 31일짜리 12개월 달력을 만들도록 Table 을 구성해보도록 하겠습니다.

먼저 테이블은 오른쪽으로 TD가 7칸을 만들어서 Loop 를 이용하여 아래쪽으로 사각형 모양이 만들어지도록 Html 을 구성해야 되겠죠?(어차피 코드 복사해서 붙혀넣으실거니깐 생략함따^^;)

그리고 ASP의 Date() 함수를 이용하여 오늘 현재의 날짜를 기준점으로하여 모든 날짜가 DateDiff(두날짜간 차이) 와 DateAdd(날짜에 대한 가감일) 함수등의 날짜함수들을 이용하여 계산할수가 있을것 같습니다.

이러다가 달력 언제 만들어요? 하시는 분들도 계시겠지만 아직도 갈길이 멀군요^^;

기능적인 면에서 볼때 Function 을 정의하여 실제 화면에 출력되는 부분을 코딩할때는 적극 활용하는 형태로 소스의 지저분한 면을 알아보기 쉽게 물밑작업을 먼저 해 두어야 합니다.

그래서 먼저 필요한 몇가지들을 먼저 만들어 보려고 합니다.

파일명은 cal_logic.asp로 해두시고 먼저 소스를 보면서 설명드리기로 하겠습니다.

/calendar/cal_logic.asp

<%
intThisYear=Request("F_Year") '년도넘겨받기
intThisMonth=Request("F_Month") '월 넘겨받기
intThisDay=Request("F_Day") '일 넘겨받기

datToday=Date() '오늘 날짜

NowThisYear=Year(datToDay) ' 현재연도값
NowThisMonth=Month(datToday) '현재 월값
NowThisDay=Day(datToday) '오늘 날짜 값

if intThisYear="" then '만약 년도와 월값을 넘겨받지 않았다면
intThisYear=NowThisYear '현재 년도를 년도 변수에
intThisMonth=NowThisMonth ' 현재 월을 월 변수에
end if

if intThisDay="" then
intThisDay=NowThisDay '현재 날짜를 일 변수에
end if

if intThisMonth=1 then '1월달이라면
    intPrevYear=intThisYear-1 '이전달 년도 = 이번년도 - 1
    intPrevMonth=12 '이전달= 12월
    intNextYear=intThisYear '다음달 년도 = 이번달 년도
    intNextMonth=2 '다음달= 2월
elseif intThisMonth=12 then '12월달이라면
    intPrevYear=intThisYear '이전달 년도 = 이번달 년도
    intPrevMonth=11 '이전달= 11월
    intNextYear=intThisYear + 1 '다음달 년도 = 이번달 년도 + 1
    intNextMonth=1 ' 다음달= 1월
else '1월과 12월을 제외한 경우에는
    intPrevYear=intThisYear '이전달 년도 = 이번달 년도
    intPrevMonth=intThisMonth -1 '이전달 = 이번달 - 1
    intNextYear=intThisYear '다음달 년도 = 이번달 년도
    intNextMonth=intThisMonth+1 '다음달 = 이번달 + 1
end if

call exec_LastDay(intThisMonth,intThisYear) '이번달의 월말값 계산
intLastDay=datLastDay

call exec_LastDay(intPrevMonth,intPrevYear) '지난달의 월말값 계산
intPrevLastDay=datLastDay

call exec_LastDay(intNextMonth,intNextYear) '다음달의 월말값 계산
intNextLastDay=datLastDay

datFirstDay=DateSerial(intThisYear, intThisMonth, 1) '넘겨받은 날짜의 월초기값 파악
intFirstWeekday=Weekday(datFirstDay, vbSunday) '넘겨받은 날짜의 주초기값 파악

datThisDay=cdate(intThisYear&"-"&intThisMonth&"-"&intThisDay) '해당 년-월-일의 날짜변환
intThisWeekday=Weekday(datThisDay) '해당 날짜의 요일값

Select Case intThisWeekday
    Case 1
        varThisWeekday="일"
    Case 2
        varThisWeekday="월"
    Case 3
        varThisWeekday="화"
    Case 4
        varThisWeekday="수"
    Case 5
        varThisWeekday="목"
    Case 6
        varThisWeekday="금"
    Case 7
        varThisWeekday="토"
End Select

intPrintDay=1 '출력 초기일 값은 1부터

Stop_Flag=0
dim datLastDay
function exec_LastDay(datMonth,datYear)
if datMonth=4 or datMonth=6 or datMonth=9 or datMonth= 11 then '4월 6월 9월 11월이면 월말값은 30일
 datLastDay=30
elseif datMonth=2 and not (datYear mod 4) = 0 then '2월이고 년도를 4로 나눈 값이 0이 아니면 28일
 datLastDay=28
elseif datMonth=2 and (datYear mod 4) = 0 then '윤달 계산
 if (datYear mod 100) = 0 then
 if (datYear mod 400) = 0 then
 datLastDay=29
 else
 datLastDay=28
 end if
 else
 datLastDay=29
 end if
else
 datLastDay=31
end if
end function
%>

나름대로 열심히 주석을 단다고 달았는데도 약간의 설명이 필요할것같네요.

Get방식으로(aaa.asp?aa=1 여기서 aa 의 값은 Get 방식입니다.) 년도와 날짜를 항상 가지고 다니면서 그 날이 속한 연도, 그날이 속한 월 등등...을 매번 계산해야 하기때무에 Function 으로 정의해놓은것입니다.

intThisYear=Request("F_Year") '년도넘겨받기
intThisMonth=Request("F_Month") '월 넘겨받기
intThisDay=Request("F_Day") '일 넘겨받기

이렇게 3개의 값으로 이번달, 다음달, 이전달의 월말값, 요일, 윤달을 계산하여 return 해주게 됩니다.

이정도로 해서 기본적으로 로직은 만들어진것같구요. 이번엔 Get으로 넘겨받은 양력이라는 사실을 다 아실겁니다. 이 날짜가 대체 음력으로 몇일쯤 되는지의 로직도 만들어야 겠군요.

또한 이 음력날짜가 양력으로 몇일쯤 되는지도 알아야 될것같습니다. 왜냐구요? 추석이나 설날은 음력으로 저장되어있기에 어디에 출력할지 알아야 될거 아니겠어요? ^-^

소스를 보시죠.

/calendar/cal_lunartosol.asp

<%
dim exyear,exmonth,exday,exyuk,exddi
Function gf_lun2sol(gf_year,gf_month,gf_day,howconvert)

LTBLSTR="1212122322121-1212121221220-1121121222120-2112132122122-2112112121220-2121211212120-2212321121212-2122121121210-2122121212120-1232122121212-1212121221220-1121123221222-1121121212220-1212112121220-2121231212121-2221211212120-1221212121210-2123221212121-2121212212120-1211212232212-1211212122210-2121121212220-1212132112212-2212112112210-2212211212120-1221412121212-1212122121210-2112212122120-1231212122212-1211212122210-2121123122122-2121121122120-2212112112120-2212231212112-2122121212120-1212122121210-2132122122121-2112121222120-1211212322122-1211211221220-2121121121220-2122132112122-1221212121120-2121221212110-2122321221212-1121212212210-2112121221220-1231211221222-1211211212220-1221123121221-2221121121210-2221212112120-1221241212112-1212212212120-1121212212210-2114121212221-2112112122210-2211211412212-2211211212120-2212121121210-2212214112121-2122122121120-1212122122120-1121412122122-1121121222120-2112112122120-2231211212122-2121211212120-2212121321212-2122121121210-2122121212120-1212142121212-1211221221220-1121121221220-2114112121222-1212112121220-2121211232122-1221211212120-1221212121210-2121223212121-2121212212120-1211212212210-2121321212221-2121121212220-1212112112210-2223211211221-2212211212120-1221212321212-1212122121210-2112212122120-1211232122212-1211212122210-2121121122210-2212312112212-2212112112120-2212121232112-2122121212110-2212122121210-2112124122121-2112121221220-1211211221220-2121321122122-2121121121220-2122112112322-1221212112120-1221221212110-2122123221212-1121212212210-2112121221220-1211231212222-1211211212220-1221121121220-1223212112121-2221212112120-1221221232112-1212212122120-1121212212210-2112132212221-2112112122210-2211211212210-2221321121212-2212121121210-2212212112120-1232212122112-1212122122120-1121212322122-1121121222120-2112112122120-2211231212122-2121211212120-2122121121210-2124212112121-2122121212120-1212121223212-1211212221220-1121121221220-2112132121222-1212112121220-2121211212120-2122321121212-1221212121210-2121221212120-1232121221212-1211212212210-2121123212221-2121121212220-1212112112220-1221231211221-2212211211220-1212212121210-2123212212121-2112122122120-1211212322212-1211212122210-2121121122120-2212114112122-2212112112120-2212121211210-2212232121211-2122122121210-2112122122120-1231212122212-1211211221220-2121121321222-2121121121220-2122112112120-2122141211212-1221221212110-2121221221210-2114121221221" '2050

LTBL = Split(LTBLSTR,"-")

LDAYSTR="31-0-31-30-31-30-31-31-30-31-30-31"
LDAY = Split(LDAYSTR,"-")

DT = LTBL

YUKSTR="갑-을-병-정-무-기-경-신-임-계"
YUK=Split(YUKSTR,"-")

GAPSTR="자-축-인-묘-진-사-오-미-신-유-술-해"
GAP=Split(GAPSTR,"-")

DDISTR="쥐-소-호랑이-토끼-용-뱀-말-양-원숭이-닭-개-돼지"
DDI=Split(DDISTR,"-")

WEEKSTR="일-월-화-수-목-금-토"
WEEK=Split(WEEKSTR,"-")

If gf_Year <= 1881 Or gf_Year >= 2050 Then '년수가 해당일자를 넘는 경우
gf_Is_Yun = 0
%>
<script language="javascript">
<!--
alert("년도가 범위를 벗어납니다. \n\n1882년부터 2049년사이의 년도를 입력하세요.");

history.back();
//-->
</script>
<%
End If
If gf_Month + 1 > 13 Then '달수가 13이 넘는 경우
gf_Is_Yun = 0
%>
<script language="javascript">
<!--
alert("달수가 범위를 벗어납니다. \n\n1월부터 12월사이의 달을 입력하세요.");

history.back();
//-->
</script>
<%
End If

M1 = gf_Year - 1881
If Mid(LTBL(M1), 13, 1) = 0 Then '윤달이 없는 해임
 gf_Is_Yun = 0
Else
 If Mid(LTBL(M1), gf_Month + 1, 1) > 2 Then
 gf_Is_Yun = 1
 Else
 gf_Is_Yun = 0
 End If
End If

if howconvert="1" then
'------------------------양력변환--------------------

M1 = -1
 TD = 0

 If gf_Year > 1881 And gf_Year < 2050 Then
 M1 = gf_Year - 1882
 For I = 0 To M1
 For J = 1 To 13
 TD = TD + CLng(Mid(LTBL(I), J, 1))
 Next
 If Mid(LTBL(I), 13, 1) = 0 Then
 TD = TD + 336
 Else
 TD = TD + 362
 End If
 Next
 Else
 GF_LUN2SOL = 0
 End If

 M1 = M1 + 1
 N2 = gf_Month - 1
 M2 = -1

 Do
 M2 = M2 + 1
 If Mid(LTBL(M1), M2 + 1, 1) > 2 Then
 TD = TD + 26 + CLng(Mid(LTBL(M1), M2 + 1, 1))
 N2 = N2 + 1
 Else
 If M2 = N2 Then
 If GF_YUN = True Then
 TD = TD + 28 + CLng(Mid(LTBL(M1), M2 + 1, 1))
 End If
 Exit Do
 Else
 TD = TD + 28 + CLng(Mid(LTBL(M1), M2 + 1, 1))
 End If
 End If
 Loop

 TD = TD + CLng(GF_DAY) + 29
 M1 = 1880
 Do
 M1 = M1 + 1
 If M1 Mod 400 = 0 Or M1 Mod 100 <> 0 And M1 Mod 4 = 0 Then
 LEAP = 1
 Else
 LEAP = 0
 End If

 If LEAP Then
 M2 = 366
 Else
 M2 = 365
 End If
 If TD < CLng(M2) Then
 Exit Do
 End If
 TD = TD - CLng(M2)
 Loop
 SYEAR = M1
 LDAY(1) = M2 - 337

M1 = 0

 Do
 M1 = M1 + 1
 If TD <= CLng(LDAY(M1 - 1)) Then
 Exit Do
 End If
 TD = TD - CLng(LDAY(M1 - 1))
 Loop
 SMONTH = M1
 SDAY = CInt(TD)
 Y = CLng(SYEAR - 1)
 TD = CLng(Y * 365) + CLng(Y / 4) - CLng(Y /100) + CLng(Y /400)

 If SYEAR Mod 400 = 0 Or SYEAR Mod 100 <> 0 And SYEAR Mod 4 = 0 Then
 LEAP = 1
 Else
 LEAP = 0
 End If

 If LEAP=1 Then
 LDAY(1) = 29
 Else
 LDAY(1) = 28
 End If
 For I = 0 To SMONTH - 2
 TD = TD + CLng(LDAY(I))
 Next
 TD = TD + CLng(SDAY)
 W = CInt(TD Mod 7)

 sweek = WEEK(W)
 GF_LUN2SOL = 1

    exyear=syear
    exmonth=smonth
    exday=sday
    exweek=sweek

else
'------------------------음력변환--------------------
 For I = 0 To 168
 DT(I) = 0
 For J = 1 To 12
 Select Case Mid(LTBL(I), J, 1)
 Case 1, 3
 DT(I) = DT(I) + 29
 Case 2, 4
 DT(I) = DT(I) + 30
 End Select
 Next

 Select Case Mid(LTBL(I), 13, 1)
 Case 0
 Case 1, 3
 DT(I) = DT(I) + 29
 Case 2, 4
 DT(I) = DT(I) + 30
 End Select
 Next
 TD1 = CLng(CLng(1880) * CLng(365)) + 1880 \ 4 - 1880 \ 100 + 1880 \ 400 + 30
 K11 = CLng(gf_Year - 1)
 TD2 = K11 * CLng(365) + K11 \ 4 - K11 \ 100 + K11 \ 400

 If gf_Year Mod 400 = 0 Or gf_Year Mod 100 <> 0 And gf_Year Mod 4 = 0 Then
 LDAY(1) = 29
 Else
 LDAY(1) = 28
 End If
 If gf_Month > 13 Then
 GF_SOL2LUN = 0
 End If
 If GF_DAY > LDAY(gf_Month - 1) Then
 GF_SOL2LUN = 0
 End If

 For I = 0 To gf_Month - 2
 TD2 = TD2 + CLng(LDAY(I))
 Next
 TD2 = TD2 + CLng(GF_DAY)
 TD = TD2 - TD1 + 1
 TD0 = CLng(DT(0))

For I = 0 To 168
 If TD <= TD0 Then
 Exit For
 End If
 TD0 = TD0 + CLng(DT(I + 1))
 Next

 rYear = I + 1881
 TD0 = TD0 - CLng(DT(I))
 TD = TD - TD0

 If Mid(LTBL(I), 13, 1) = 0 Then
 JCOUNT = 11
 Else
 JCOUNT = 12
 End If
 M2 = 0

 For J = 0 To JCOUNT '달수 check, 윤달 > 2 (by harcoon)
 If Mid(LTBL(I), J + 1, 1) <= 2 Then
 M2 = M2 + 1
 M1 = Mid(LTBL(I), J + 1, 1) + 28
 GF_YUN = 0
 Else
 M1 = Mid(LTBL(I), J + 1, 1) + 26
 GF_YUN = 1
 End If
 If TD <= CLng(M1) Then
 Exit For
 End If
 TD = TD - CLng(M1)
 Next

    k1=(ryear+6) Mod 10
    syuk = YUK(k1)
    k2=(ryear+8) Mod 12
    sgap = GAP(k2)
    sddi=DDI(k2)

    GF_SOL2LUN = 1

exyear=ryear
 if int(M2) < 10 then
 exmonth = "0"&M2
 else
 exmonth = M2
 end if
 if int(TD) < 10 then
 exday = "0"&TD
 else
 exday = TD
 end if
 exyuk=syuk&sgap
 exddi=sddi
end if
end function
%>

열심히 Function 만들어 보았습니다.

이 Function 은 gf_lun2sol(년도,월,일,변경할 타입) 으로서 변경할 타입을 1을 넣으면 양=>음 으로 변환해주고요, 1이 아닌 다른값을 넣으면 음=>양으로 변환해 준답니다.(이런 좋은것이^^)

이 Function 은 다른소스에서도 유용하게 사용하실수 있으리라 믿구요.(아마도 더 좋은 소스가 있을것이지만 바쁘다는 핑계로 찾지 못했습니다.^^)

음력=>양력 , 혹은 양력=>음력 변경할때 사용되는 기법은 대니가 2001년도에 한국천문연구원(?) 을 참고, 타 캘린더 소스들을 참고로 해서 적용했었는데 정확한 기억는 나지 않지만 궂이 여러분에게 로직을 다 이해하라고 말씀드리지는 않겠습니다(특히 머리숫이 적으신분들은 그냥 소스 긁어가는정도로 ... 미련남기지 마세요...)

LTBLSTR 값은 다운받아서 활용하였고 변환로직은 연구결과가 나오면 그걸 활용하기때문에 만년달력 양음력변환은 아직 없는것으로 알고있습니다.(변환을 하더라도 오차가 있어서 그런것임.)

그 다음으로 필요한것은 바로 기념일입니다.

이 기념일만없어도 달력이 깔끔해지는데 기념일때문에 "오늘이 몇째주인가?" , "오늘이 양(음)력몇일인가?" 등의 의문이 자꾸만 생기게 된답니다. 여기서 그냥 넘어갈수없는 도대체 오늘이 몇째주인가를 저두 많이 고민했습니다.

월	화	수	목	금	토	일
			1	2	3	4
5	6	7	8	9	10	11

여기서 6일과 9일은 과연 몇째주 일까요?

첫째주라구요? 아니 둘째주라구요?(의견이 분분할 것 같기도 하지만... 저혼자 설치는건 아닌지..ㅡㅡ;)

9일이 첫째주라면 그럼 2일은 몇째준가요? 0째주?

그럼 6일이 첫째주라면 9일은 2째주? 같은주 아닌가요?

만약 6일이 둘째주라면 그럼 이달의 첫째주 화요일날 모임있으시는 분들은 안모이나요?

이렇게 생긴달이 한두번 있는것도 아닌데 말이죠... 이걸 어떻게 이해해야 할까요?

그렇다면 성년의날을 짚고 넘어가야 할것같습니다.

2004년 성년의 날은 5월 17일 이었습니다.(달력을 보시면서 읽으시면 이해하시기 편합니다.)

그럼 2005년은? 16일이네요, 2006년은 15일입니다.

그렇다면 이건 어떻게 계산되었을까요?

달력을 계속 넘기면서 보신분들이라면 6일은 첫째주이며 9일은 둘째주라고 계산되었다는것을 아실수 있을겁니다. 이렇게 같은주 일지라도 "오늘이 몇째주인가 ?" 로 계산하면 다르다는 사실을 알수 있었습니다.

그래서 대니는 만들어보았습니다. 뭐를? 오늘이 몇째주 인지를...

대니의 삽질코드 들어갑니다.

date2 = "2001-01-27" //몇째주인지 알고싶은 날짜
결과 = round((datediff("d",mid(date(),1,7)&"-01",date2)+weekday(date1))/7 -0.5)+1

response.write 결과&"주"

이렇게 죽어라고 해보았습니다. 화면에 찍어보면서 말이죠..(여러분들도 화면에 찍어보잖아요^^;)

그랫더니 잘 나오더랍니다. 몇째주인지... 그래서 제가 운영하는 산소사이트에 팁이랍시고 올려보았습지요. 뭐 올릴때까지야... 다 똑같은 기분... 그랫더니 얼마못가 댓글이 달렸더랍니다.

딴지는 아니구요. DateDiff("ww", Left(Date(), 7) & "-01", Date()) + 1 가 조금 더 쉬울듯...

음... 결과는 저도 모르겠습니다. 간혹 열심히 해서 삽질코드 만들어내서 챙피당하는일이 너무 빈번해져서 자중모드 들어감니다.( --)

2탄에서 보시겠지만 이 소스는 당연히 위에꺼(첫번째)로 되어있지요.

여러분들이 나름대로 분석해서 적용하셔도 될것같습니다. 나머지 기념일은 모두 위에 정의된 function 을 이용하여 쉽게 달력에 출력할수가 있을것같네요. 그럼 이제 기념일을 정의하는 파일을 하나 더 만들어보죠.

<%
'양력 기념일
holiday_icon = " <img src=calendar/cal_img/koreanflag.jpg border=0 width=12 alt='반복일정'>"
function holiday(danny1,danny2)
 danny_td = danny1&"-"&danny2
 select case danny_td
 case "01-01"
 danny_today = holiday_icon&" 신정 "
 case "01-14"
 danny_today = holiday_icon&" 다이어리데이 "
 case "02-14"
 danny_today = holiday_icon&" 발렌타인데이 "
 case "03-01"
 danny_today = holiday_icon&" 삼일절 "
 case "03-03"
 danny_today = holiday_icon&" 납세자의날 "
 case "03-14"
 danny_today = holiday_icon&" 화이트데이 "
 case "03-19"
 danny_today = holiday_icon&" 상공의날 "
 case "03-22"
 danny_today = holiday_icon&" 물의날 "
 case "03-23"
 danny_today = holiday_icon&" 기상의날 "
 case "03-24"
 danny_today = holiday_icon&" 세계결핵의날 "
 case "04-05"
 danny_today = holiday_icon&" 식목일 "
 danny_today = danny_today&holiday_icon&" 청명 "
 danny_today = danny_today&holiday_icon&" 향토예비군의날 "
 case "04-07"
 danny_today = holiday_icon&" 보건의날 "
 case "04-13"
 danny_today = holiday_icon&" 임시정부수립기념 "
 case "04-14"
 danny_today = holiday_icon&" 블랙데이 "
 case "04-19"
 danny_today = holiday_icon&" 4.19혁명기념일 "
 case "04-20"
 danny_today = holiday_icon&" 장애인의날 "
 case "04-21"
 danny_today = holiday_icon&" 과학의날 "
 case "04-22"
 danny_today = holiday_icon&" 정보통신의날 "
 case "04-28"
 danny_today = holiday_icon&" 충무공탄신일 "
 case "05-01"
 danny_today = holiday_icon&" 근로자의날 "
 danny_today = danny_today&holiday_icon&" 법의날 "
 case "05-05"
 danny_today = holiday_icon&" 어린이날 "
 case "05-08"
 danny_today = holiday_icon&" 어버이날 "
 case "05-14"
 danny_today = holiday_icon&" 로즈데이 "
 case "05-15"
 danny_today = holiday_icon&" 스승의날 "
 case "05-18"
 danny_today = holiday_icon&" 5.18 민주화운동 "
 case "05-19"
 danny_today = holiday_icon&" 발명의날 "
 case "05-25"
 danny_today = holiday_icon&" 방재의날 "
 case "05-31"
 danny_today = holiday_icon&" 바다의날 "
 case "06-05"
 danny_today = holiday_icon&" 환경의날 "
 case "06-06"
 danny_today = holiday_icon&" 현충일 "
 case "06-14"
 danny_today = holiday_icon&" 키스데이 "
 case "06-25"
 danny_today = holiday_icon&" 6.25사변일 "
 case "07-14"
 danny_today = holiday_icon&" 실버데이 "
 case "07-17"
 danny_today = holiday_icon&" 제헌절 "
 case "08-14"
 danny_today = holiday_icon&" 뮤직데이 "
 case "08-15"
 danny_today = holiday_icon&" 광복절 "
 case "09-14"
 danny_today = holiday_icon&" 포토데이 "
 case "09-18"
 danny_today = holiday_icon&" 철도의날 "
 case "10-01"
 danny_today = holiday_icon&" 국군의날 "
 case "10-02"
 danny_today = holiday_icon&" 노인의날 "
 case "10-03"
 danny_today = holiday_icon&" 개천절 "
 case "10-09"
 danny_today = holiday_icon&" 한글날 "
 case "10-14"
 danny_today = holiday_icon&" 와인데이 "
 case "10-15"
 danny_today = holiday_icon&" 체육의날 "
 case "10-20"
 danny_today = holiday_icon&" 문화의날 "
 case "10-21"
 danny_today = holiday_icon&" 경찰의날 "
 case "10-24"
 danny_today = holiday_icon&" 국제연합일 "
 case "10-28"
 danny_today = holiday_icon&" 저축의날 "
 case "11-03"
 danny_today = holiday_icon&" 학생의날 "
 case "11-09"
 danny_today = holiday_icon&" 소방의날 "
 case "11-11"
 danny_today = holiday_icon&" 농업인의날 "
 case "11-14"
 danny_today = holiday_icon&" 무비데이 "
 case "11-17"
 danny_today = holiday_icon&" 순국선열의날 "
 case "11-30"
 danny_today = holiday_icon&" 무역의날 "
 case "12-03"
 danny_today = holiday_icon&" 소비자의날 "
 case "12-05"
 danny_today = holiday_icon&" 국민교육헌장선포 "
 case "12-10"
 danny_today = holiday_icon&" 세계인권선언기념 "
 case "12-14"
 danny_today = holiday_icon&" 허그데이 "
 case "12-25"
 danny_today = holiday_icon&" 성탄절 "
 end select
end function

'음력기념일
function holiday_lunar(danny3,danny4)
 danny_lu = danny3&"-"&danny4
 select case danny_lu
 case "01-01"
 danny_lunar = holiday_icon&" 설날 "
 case "01-04"
 danny_lunar = holiday_icon&" 입춘 "
 case "01-19"
 danny_lunar = holiday_icon&" 우수 "
 case "02-04"
 danny_lunar = holiday_icon&" 경칩 "
 case "02-19"
 danny_lunar = holiday_icon&" 춘분 "
 case "03-05"
 danny_lunar = holiday_icon&" 한식 "
 case "04-06"
 danny_lunar = holiday_icon&" 입하 "
 case "04-21"
 danny_lunar = holiday_icon&" 소만 "
 case "05-05"
 danny_lunar = holiday_icon&" 단오 "
 case "05-23"
 danny_lunar = holiday_icon&" 하지 "
 case "06-08"
 danny_lunar = holiday_icon&" 소서 "
 case "06-17"
 danny_lunar = holiday_icon&" 초복 "
 case "06-24"
 danny_lunar = holiday_icon&" 대서 "
 case "06-27"
 danny_lunar = holiday_icon&" 중복 "
 case "07-07"
 danny_lunar = holiday_icon&" 칠석 "
 case "07-11"
 danny_lunar = holiday_icon&" 입추 "
 case "07-18"
 danny_lunar = holiday_icon&" 말복 "
 case "07-26"
 danny_lunar = holiday_icon&" 처서 "
 case "08-12"
 danny_lunar = holiday_icon&" 백로 "
 case "08-15"
 danny_lunar = holiday_icon&" 추석 "
 case "08-27"
 danny_lunar = holiday_icon&" 추분 "
 case "09-29"
 danny_lunar = holiday_icon&" 상강 "
 case "10-15"
 danny_lunar = holiday_icon&" 입동 "
 case "10-30"
 danny_lunar = holiday_icon&" 소설 "
 case "11-14"
 danny_lunar = holiday_icon&" 대설 "
 case "11-29"
 danny_lunar = holiday_icon&" 동지 "
 end select
end function
%>

정말 무식한 대니입니다. 이걸 이렇게 만들었다니...

지금이야 XML이 있어서 파일DB를 이용하면 편하겠지만 이때 대니는 회사에서 죽어라 일하고 집에서 잠잘시간에 코딩할때여서 XML이 없었거나 대니가 XML을 모를때였습니다.(솔직히 말씀드리면 이부분때문에 일정관리가 매우 느려졌으며 서버도 죽일려고 덤벼든답니다.)

이부분은 작업하시는분이 업그레이드를 좀 하시면 좋을것같다는 대니의 짧은 바램이었습니다.

위의 코드는 대니가 직접 탁상달력을 들고서 타이핑했기때문에 간혹 오타나 기념일이 잘못입력되었을수도 있다는 말씀을 드립니다.(그래도 나름대로 모두 체크해보았음^^)

기념일은 음력기념일 function 과 양력기념일 function 으로 구분되어있으며 코드에 대해서는 보는것으로 충분히 이해하실수 있으리라고 생각됩니다.

이정도로 해서 실제 달력만들기 #1에서는 달력을 만들기 위한 물밑작업을 준비해 보았습니다.

실제 달력을 만들어서 적용하는것 만큼이나 이 부분은 중요한 부분이며 이 부분이 실제 개발할때 많은 시간과 이해가 들어간다는점도 참고하셨으면 좋겠다는 생각을 해봅니다.

달력만들기 #2 에서 계속하기로 하겠습니다.

점점 드러나는 대니의 잡코드들이 드러나면서 좀 챙피한것도 사실이지만 실제 개발을 앞두고 있으신 분들이나 ASP를 공부하시는 분들에게 약간이나마 도움이 된다면....이라는 생각으로 힘내서 연재하도록 하겠습니다.

이번강좌는 그림이 없으면서도 너무 아래로만 내려온것같다는 생각이..^^;

이 글 읽으시는분들 모두 좋은 하루 되시고 대니는 이만 일정관리 3탄에서 뵙기로 하겠습니다.

홧팅~!!! 아자아자~!!(썰렁~ --;;;)

Back